stdlib/termios.tl


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80

;; Copyright 2016-2024
;; Kaz Kylheku <kaz@kylheku.com>
;; Vancouver, Canada
;; All rights reserved.
;;
;; Redistribution and use in source and binary forms, with or without
;; modification, are permitted provided that the following conditions are met:
;;
;; 1. Redistributions of source code must retain the above copyright notice,
;;    this list of conditions and the following disclaimer.
;;
;; 2. Redistributions in binary form must reproduce the above copyright notice,
;;    this list of conditions and the following disclaimer in the documentation
;;    and/or other materials provided with the distribution.
;;
;; THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS"
;; AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
;; IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
;; ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT HOLDER OR CONTRIBUTORS BE
;; LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
;; CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
;; SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
;; INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
;; CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
;; ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
;; POSSIBILITY OF SUCH DAMAGE.

(defmeth termios set-iflags (tio . values)
  (set-mask tio.iflag . values))

(defmeth termios set-oflags (tio . values)
  (set-mask tio.oflag . values))

(defmeth termios set-cflags (tio . values)
  (set-mask tio.cflag . values))

(defmeth termios set-lflags (tio . values)
  (set-mask tio.lflag . values))

(defmeth termios clear-iflags (tio . values)
  (clear-mask tio.iflag . values))

(defmeth termios clear-oflags (tio . values)
  (clear-mask tio.oflag . values))

(defmeth termios clear-cflags (tio . values)
  (clear-mask tio.cflag . values))

(defmeth termios clear-lflags (tio . values)
  (clear-mask tio.lflag . values))

(defmeth termios go-raw (tio)
  tio.(clear-iflags ignbrk brkint parmrk istrip inlcr igncr icrnl ixon)
  tio.(clear-oflags opost)
  tio.(clear-cflags csize parenb)
  tio.(clear-lflags echo echonl icanon isig)
  (if (boundp 'iexten)
    tio.(clear-lflags iexten))
  tio.(set-cflags cs8)
  (set [tio.cc vmin] 1)
  (set [tio.cc vtime] 0))

(defmeth termios go-cbreak (tio)
  tio.(clear-iflags icrnl)
  tio.(clear-lflags icanon)
  tio.(set-lflags isig)
  (set [tio.cc vmin] 1)
  (set [tio.cc vtime] 0))

(defmeth termios string-encode (tio)
  (let ((*print-base* 16))
    tio.(sys:encode-speeds)
    (downcase-str `@{tio.iflag}:@{tio.oflag}:@{tio.cflag}:@{tio.lflag}:\
                  @{(list-vec tio.cc) ":"}`)))

(defmeth termios string-decode (tio string)
  (let ((vals (mapcar (op int-str @1 16) (split-str string ":"))))
    (lset tio.iflag tio.oflag tio.cflag tio.lflag vals)
    (set tio.cc (vec-list (cddddr vals)))
    tio.(sys:decode-speeds)))