stdlib/build.tl


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149

;; Copyright 2016-2024
;; Kaz Kylheku <kaz@kylheku.com>
;; Vancouver, Canada
;; All rights reserved.
;;
;; Redistribution and use in source and binary forms, with or without
;; modification, are permitted provided that the following conditions are met:
;;
;; 1. Redistributions of source code must retain the above copyright notice,
;;    this list of conditions and the following disclaimer.
;;
;; 2. Redistributions in binary form must reproduce the above copyright notice,
;;    this list of conditions and the following disclaimer in the documentation
;;    and/or other materials provided with the distribution.
;;
;; THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS"
;; AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
;; IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
;; ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT HOLDER OR CONTRIBUTORS BE
;; LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
;; CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
;; SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
;; INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
;; CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
;; ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
;; POSSIBILITY OF SUCH DAMAGE.

(defun sys:list-builder-flets (lb-form)
  (nconc
    (collect-each ((op '(add add* pend pend* ncon ncon* oust)))
      ^(,op (. args)
         (qref ,lb-form (,op . args))
         nil))
    ^((get ()
        (qref ,lb-form (get)))
      (del* ()
        (qref ,lb-form (del*)))
      (do-del ()
        (qref ,lb-form (del))))))

(defun sys:build-expander (forms return-get)
  (with-gensyms (name)
    ^(let ((,name (new list-builder)))
       (flet ,(sys:list-builder-flets name)
         (macrolet ((del (:form f : (expr nil expr-p))
                      (if expr-p f '(do-del))))
           ,*forms
           ,*(if return-get ^((qref ,name (get)))))))))

(defmacro build (. forms)
  (sys:build-expander forms t))

(defmacro buildn (. forms)
  (sys:build-expander forms nil))

(defstruct list-builder ()
  head tail

  (:postinit (self)
    (set self.head (cons nil self.head)
         self.tail self.head))

  (:method oust (self . lists)
    (if lists
      (let ((nl [apply append lists]))
        (set self.tail (usr:rplacd self.head nl)))
      (set self.tail (usr:rplacd self.head nil)))
    self)

  (:method add (self . items)
    (let ((st self.tail))
      (rplacd st (append (cdr st) nil))
      (let ((tl (last st)))
        (usr:rplacd tl (append (cdr tl) items))
        (set self.tail tl)))
    self)

  (:method add* (self . items)
    (let ((h self.head))
      (usr:rplacd h (append items (cdr h))))
    self)

  (:method pend (self . lists)
    (when lists
      (let ((st self.tail))
        (rplacd st (append (cdr st) nil))
        (let* ((tl (last st))
               (cp (tailp tl (car (last lists))))
               (nl [apply append lists]))
          (usr:rplacd tl (append (cdr tl) (if cp (copy-list nl) nl)))
          (set self.tail tl)))
      self))

  (:method pend* (self . lists)
    (let* ((h self.head)
           (pf [apply append (append lists (list (cdr h)))]))
      (usr:rplacd h pf)
      (set self.tail h))
    self)

  (:method ncon (self . lists)
    (when lists
      (let* ((tl (last self.tail))
             (nl [apply nconc lists]))
        (usr:rplacd tl (nconc (cdr tl) nl))
        (set self.tail tl))
      self))

  (:method ncon* (self . lists)
    (let* ((h self.head)
           (pf [apply nconc (append lists (list (cdr h)))]))
      (usr:rplacd h pf)
      (if (eq self.tail h)
        (set self.tail pf)))
    self)

  (:method get (self)
    (cdr self.head))

  (:method del (self)
    (whenlet ((hd self.head)
              (chd (cdr self.head)))
      (when (eq self.tail chd)
        (set self.tail hd))
      (prog1 (car chd) (usr:rplacd hd (cdr chd)))))

  (:method del* (self)
    (whenlet ((hd self.head)
              (chd (cdr self.head)))
      (if (cdr chd)
        (let* ((tl self.tail)
               (l2 (nthlast 2 tl)))
          (if (cdr l2)
            (prog1
              (cadr l2)
              (usr:rplacd l2 nil))
            (let* ((l10 (nthlast 10 hd))
                   (l2 (nthlast 2 l10)))
              (prog1
                (cadr l2)
                (usr:rplacd l2 nil)
                (set self.tail l10)))))
        (prog1
          (car chd)
          (usr:rplacd hd nil)
          (set self.tail hd))))))

(defun build-list (: init)
  (new list-builder head init))