2011-12-15 Konrad Eisele <konrad@gaisler.com>

        * configure.in: Add SPARC LEON support.
        * configure: Regenerated.
        * sparc_leon/asm-leon/amba.h, sparc_leon/asm-leon/asmmacro.h,
        sparc_leon/asm-leon/clock.h, sparc_leon/asm-leon/contextswitch.h,
        sparc_leon/asm-leon/elfmacro.h, sparc_leon/asm-leon/head.h,
        sparc_leon/asm-leon/irq.h, sparc_leon/asm-leon/jiffies.h,
        sparc_leon/asm-leon/lambapp.h, sparc_leon/asm-leon/lambapp_devs.h,
        sparc_leon/asm-leon/leon.h, sparc_leon/asm-leon/leon3.h,
        sparc_leon/asm-leon/leonbare_debug.h, sparc_leon/asm-leon/leonbare_kernel.h,
        sparc_leon/asm-leon/leonbare_kernel_queue.h, sparc_leon/asm-leon/leoncompat.h,
        sparc_leon/asm-leon/leondbg.h, sparc_leon/asm-leon/leonstack.h,
        sparc_leon/asm-leon/liblocks.h, sparc_leon/asm-leon/linkage.h,
        sparc_leon/asm-leon/param.h, sparc_leon/asm-leon/queue.h,
        sparc_leon/asm-leon/spinlock.h, sparc_leon/asm-leon/stack.h,
        sparc_leon/asm-leon/time.h, sparc_leon/asm-leon/timer.h,
        sparc_leon/asm-leon/types.h, sparc_leon/asm-leon/winmacros.h:
        New file.
        * sparc_leon/Makefile.in, sparc_leon/_exit.c,
        sparc_leon/amba.c, sparc_leon/amba_dbg.c,
        sparc_leon/amba_driver.c, sparc_leon/amba_scan.c,
        sparc_leon/asm-leon, sparc_leon/bdinit.S,
        sparc_leon/busscan.S, sparc_leon/cacheA.S,
        sparc_leon/catch_interrupt.c, sparc_leon/catch_interrupt_mvt.c,
        sparc_leon/catch_interrupt_pending.c, sparc_leon/catch_interrupt_svt.c,
        sparc_leon/configure.in,
        sparc_leon/console.c, sparc_leon/console_dbg.c,
        sparc_leon/console_init.c, sparc_leon/contextswitch.c,
        sparc_leon/contextswitch_asm.S, sparc_leon/crt0.S,
        sparc_leon/crti.S, sparc_leon/crtn.S,
        sparc_leon/etrap.S, sparc_leon/etrap_fast.S,
        sparc_leon/fpu.S, sparc_leon/gettimeofday.c,
        sparc_leon/initcalls.c, sparc_leon/io.c,
        sparc_leon/irqinstall.S, sparc_leon/irqtrap.S,
        sparc_leon/irqtrap_fast.S, sparc_leon/jiffies.c,
        sparc_leon/kernel.c, sparc_leon/kernel_context.S,
        sparc_leon/kernel_debug.c, sparc_leon/kernel_debug_var.c,
        sparc_leon/kernel_mm.c, sparc_leon/kernel_mutex.c,
        sparc_leon/kernel_queue.c, sparc_leon/kernel_sched.c,
        sparc_leon/kernel_thread.c, sparc_leon/lcpuinit.S,
        sparc_leon/locore.S, sparc_leon/locore_atexit.c,
        sparc_leon/locore_clean.S, sparc_leon/locore_mvt.S,
        sparc_leon/locore_mvt_reset.S, sparc_leon/locore_svt.S,
        sparc_leon/locore_svt_reset.S, sparc_leon/locore_svtdisp.S,
        sparc_leon/locore_var.S, sparc_leon/locore_var_svt.S,
        sparc_leon/mmu_asm.S, sparc_leon/mutex.c,
        sparc_leon/nocache.S, sparc_leon/pnpinit.c,
        sparc_leon/pnpinit_malloc.c, sparc_leon/pnpinit_simple.c,
        sparc_leon/regwin.S, sparc_leon/regwin_patch.c,
        sparc_leon/regwin_slow.S, sparc_leon/regwinflush.S,
        sparc_leon/rtc.c, sparc_leon/rtrap.S,
        sparc_leon/rtrap_fast.S, sparc_leon/stop.S,
        sparc_leon/timer.c, sparc_leon/times.c:
        New file
        * sparc_leon/configure: Regenerate

1 files changed, 135 insertions, 0 deletions

diff --git a/libgloss/sparc_leon/regwin_slow.S b/libgloss/sparc_leon/regwin_slow.S
new file mode 100644
index 000000000..619183428
--- /dev/null
+++ b/libgloss/sparc_leon/regwin_slow.S
@@ -0,0 +1,135 @@
+/*
+ * Copyright (c) 2011 Aeroflex Gaisler
+ *
+ * BSD license:
+ *
+ * Permission is hereby granted, free of charge, to any person obtaining a copy
+ * of this software and associated documentation files (the "Software"), to deal
+ * in the Software without restriction, including without limitation the rights
+ * to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
+ * copies of the Software, and to permit persons to whom the Software is
+ * furnished to do so, subject to the following conditions:
+ *
+ * The above copyright notice and this permission notice shall be included in
+ * all copies or substantial portions of the Software.
+ *
+ * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
+ * IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
+ * FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL
+ * THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
+ * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
+ * OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN
+ * THE SOFTWARE.
+ */
+
+
+#include <asm-leon/leon.h>
+#include <asm-leon/leonstack.h>
+#include <asm-leon/asmmacro.h>
+        
+  .seg    "text"
+
+	
+/* Number of register windows */
+	.global _nwindows_min1, _nwindows
+	
+        ! Window overflow trap handler on save.
+        ! Touches %g1
+	/* ------- */
+	.weak	_window_overflow
+	.set	_window_overflow,__window_overflow
+	.weak	_window_overflow_svt
+	.set	_window_overflow_svt,__window_overflow_svt
+	/* ------- */
+  	!.global _window_overflow,_window_overflow_svt
+  	.global __window_overflow_rettseq,__window_overflow_rettseq_ret,__window_overflow_slow1
+
+__window_overflow_svt:		
+__window_overflow:
+#ifndef _FLAT
+__window_overflow_rettseq:		
+  	mov  %wim, %l3       		! Calculate next WIM
+  	mov  %g1, %l7           
+  	srl  %l3, 1, %g1        
+	
+__window_overflow_rettseq_ret:		
+	sethi %hi(_nwindows_min1), %l4	! NWINDOWS-1
+	ld [%l4+%lo(_nwindows_min1)], %l4
+	
+	sll  %l3, %l4 , %l4
+  	or   %l4, %g1, %g1
+
+  	save                              ! Get into window to be saved.
+  	mov  %g1, %wim
+  	nop; nop; nop
+        std   %l0, [%sp + 0];
+        std   %l2, [%sp + 8];
+        std   %l4, [%sp + 16]; 
+        std   %l6, [%sp + 24]; 
+        std   %i0, [%sp + 32]; 
+        std   %i2, [%sp + 40]; 
+        std   %i4, [%sp + 48]; 
+        std   %i6, [%sp + 56]; 
+  	restore				! Go back to trap window.
+  	mov  %l7, %g1
+	
+  	jmp  %l1			! Re-execute save.
+  	rett %l2
+	nop
+	
+__window_overflow_slow1:		! space for possible stackcheck patch
+	nop
+	nop
+#else	
+	ta	0			! halt 
+__window_overflow_rettseq:		
+__window_overflow_rettseq_ret:		
+__window_overflow_slow1:		
+	nop
+	nop
+	nop
+#endif
+	
+  /* Window underflow trap handler on restore.  */
+
+        ! Touches %g1
+	/* ------- */
+  	.weak	_window_underflow
+	.set	_window_underflow,__window_underflow
+	.weak	_window_underflow_svt
+	.set	_window_underflow_svt,__window_underflow_svt
+	/* ------- */
+  	!.global  _window_underflow,_window_underflow_svt
+
+__window_underflow_svt:
+__window_underflow:
+#ifndef _FLAT
+	mov  %wim, %l3			! Calculate next WIM
+	sll  %l3, 1, %l4
+
+	sethi %hi(_nwindows_min1), %l5	! NWINDOWS-1
+	ld [%l5+%lo(_nwindows_min1)], %l5
+	
+	srl  %l3, %l5, %l5
+  	or   %l5, %l4, %l5
+  	mov  %l5, %wim
+  	nop; nop; nop
+  	restore				! Two restores to get into the
+  	restore				! window to restore
+        ldd   [%sp + 0], %l0; 		! Restore window from the stack
+        ldd   [%sp + 8], %l2; 
+        ldd   [%sp + 16], %l4; 
+        ldd   [%sp + 24], %l6; 
+        ldd   [%sp + 32], %i0; 
+        ldd   [%sp + 40], %i2; 
+        ldd   [%sp + 48], %i4; 
+        ldd   [%sp + 56], %i6; 
+  	save				! Get back to the trap window.
+  	save
+  	jmp  %l1			! Re-execute restore.
+  	rett  %l2
+#else	
+	ta	0			! halt 
+#endif
+
+