2011-12-15 Konrad Eisele <konrad@gaisler.com>

        * configure.in: Add SPARC LEON support.
        * configure: Regenerated.
        * sparc_leon/asm-leon/amba.h, sparc_leon/asm-leon/asmmacro.h,
        sparc_leon/asm-leon/clock.h, sparc_leon/asm-leon/contextswitch.h,
        sparc_leon/asm-leon/elfmacro.h, sparc_leon/asm-leon/head.h,
        sparc_leon/asm-leon/irq.h, sparc_leon/asm-leon/jiffies.h,
        sparc_leon/asm-leon/lambapp.h, sparc_leon/asm-leon/lambapp_devs.h,
        sparc_leon/asm-leon/leon.h, sparc_leon/asm-leon/leon3.h,
        sparc_leon/asm-leon/leonbare_debug.h, sparc_leon/asm-leon/leonbare_kernel.h,
        sparc_leon/asm-leon/leonbare_kernel_queue.h, sparc_leon/asm-leon/leoncompat.h,
        sparc_leon/asm-leon/leondbg.h, sparc_leon/asm-leon/leonstack.h,
        sparc_leon/asm-leon/liblocks.h, sparc_leon/asm-leon/linkage.h,
        sparc_leon/asm-leon/param.h, sparc_leon/asm-leon/queue.h,
        sparc_leon/asm-leon/spinlock.h, sparc_leon/asm-leon/stack.h,
        sparc_leon/asm-leon/time.h, sparc_leon/asm-leon/timer.h,
        sparc_leon/asm-leon/types.h, sparc_leon/asm-leon/winmacros.h:
        New file.
        * sparc_leon/Makefile.in, sparc_leon/_exit.c,
        sparc_leon/amba.c, sparc_leon/amba_dbg.c,
        sparc_leon/amba_driver.c, sparc_leon/amba_scan.c,
        sparc_leon/asm-leon, sparc_leon/bdinit.S,
        sparc_leon/busscan.S, sparc_leon/cacheA.S,
        sparc_leon/catch_interrupt.c, sparc_leon/catch_interrupt_mvt.c,
        sparc_leon/catch_interrupt_pending.c, sparc_leon/catch_interrupt_svt.c,
        sparc_leon/configure.in,
        sparc_leon/console.c, sparc_leon/console_dbg.c,
        sparc_leon/console_init.c, sparc_leon/contextswitch.c,
        sparc_leon/contextswitch_asm.S, sparc_leon/crt0.S,
        sparc_leon/crti.S, sparc_leon/crtn.S,
        sparc_leon/etrap.S, sparc_leon/etrap_fast.S,
        sparc_leon/fpu.S, sparc_leon/gettimeofday.c,
        sparc_leon/initcalls.c, sparc_leon/io.c,
        sparc_leon/irqinstall.S, sparc_leon/irqtrap.S,
        sparc_leon/irqtrap_fast.S, sparc_leon/jiffies.c,
        sparc_leon/kernel.c, sparc_leon/kernel_context.S,
        sparc_leon/kernel_debug.c, sparc_leon/kernel_debug_var.c,
        sparc_leon/kernel_mm.c, sparc_leon/kernel_mutex.c,
        sparc_leon/kernel_queue.c, sparc_leon/kernel_sched.c,
        sparc_leon/kernel_thread.c, sparc_leon/lcpuinit.S,
        sparc_leon/locore.S, sparc_leon/locore_atexit.c,
        sparc_leon/locore_clean.S, sparc_leon/locore_mvt.S,
        sparc_leon/locore_mvt_reset.S, sparc_leon/locore_svt.S,
        sparc_leon/locore_svt_reset.S, sparc_leon/locore_svtdisp.S,
        sparc_leon/locore_var.S, sparc_leon/locore_var_svt.S,
        sparc_leon/mmu_asm.S, sparc_leon/mutex.c,
        sparc_leon/nocache.S, sparc_leon/pnpinit.c,
        sparc_leon/pnpinit_malloc.c, sparc_leon/pnpinit_simple.c,
        sparc_leon/regwin.S, sparc_leon/regwin_patch.c,
        sparc_leon/regwin_slow.S, sparc_leon/regwinflush.S,
        sparc_leon/rtc.c, sparc_leon/rtrap.S,
        sparc_leon/rtrap_fast.S, sparc_leon/stop.S,
        sparc_leon/timer.c, sparc_leon/times.c:
        New file
        * sparc_leon/configure: Regenerate

1 files changed, 112 insertions, 0 deletions

diff --git a/libgloss/sparc_leon/kernel_context.S b/libgloss/sparc_leon/kernel_context.S
new file mode 100644
index 000000000..0b8cad7aa
--- /dev/null
+++ b/libgloss/sparc_leon/kernel_context.S
@@ -0,0 +1,112 @@
+/*
+ * Copyright (c) 2011 Aeroflex Gaisler
+ *
+ * BSD license:
+ *
+ * Permission is hereby granted, free of charge, to any person obtaining a copy
+ * of this software and associated documentation files (the "Software"), to deal
+ * in the Software without restriction, including without limitation the rights
+ * to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
+ * copies of the Software, and to permit persons to whom the Software is
+ * furnished to do so, subject to the following conditions:
+ *
+ * The above copyright notice and this permission notice shall be included in
+ * all copies or substantial portions of the Software.
+ *
+ * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
+ * IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
+ * FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL
+ * THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
+ * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
+ * OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN
+ * THE SOFTWARE.
+ */
+
+
+#include <asm-leon/elfmacro.h>
+#include <asm-leon/leon.h>
+#include <asm-leon/leonstack.h>
+#include <asm-leon/contextswitch.h>
+#include <asm-leon/winmacros.h>
+#include <asm-leon/leonbare_kernel.h>
+
+	FUNC_EXPORT(_leonbare_kernel_switchto)
+	FUNC_EXPORT(_leonbare_Stop)
+
+	FUNC_IMPORT(leonbare_disable_traps)
+
+	.text
+	
+/* unsigned int _leonbare_kernel_switchto(struct leonbare_thread_ctx *thread,struct leonbare_thread_ctx *thread) */
+FUNC_BEGIN(_leonbare_kernel_switchto)
+	
+	/* =================================*/
+	/*        save context              */
+	/* =================================*/
+	
+	mov	%o0, %g1
+	mov	%o1, %g2
+	mov	%o7, %g3
+	rd	%psr, %g4                       /* psr.cwp should stay same because irq path rely on it. */
+	
+	call	leonbare_disable_traps		/* psr in %o0, modify %o0, %o1, %o7 */
+	 nop
+
+	set	TACODE_IRQCALL_FLUSH,%o1
+        ta	TACODE_IRQCALL
+	
+	st	%g4, [%g1 + LEONBARE_THREAD_CTX_STACK_PSR]	/* psr */
+	set	LEONBARE_THREAD_CTX_MAGIC,%g4
+	st	%g4, [%g1 + LEONBARE_THREAD_CTX_STACK_MAGIC]
+	
+	mov	%g3, %o7			! restore %o7
+	
+	LEONBARE_THREAD_CTX_STORE_INS(g1)
+	LEONBARE_THREAD_CTX_STORE_LOCALS(g1)
+	LEONBARE_THREAD_CTX_STORE_OUTS(g1)
+
+	/* =================================*/
+	/*        restore context           */
+	/* =================================*/
+	
+	/* check valid context stack area */
+	ld	[%g2 + LEONBARE_THREAD_CTX_STACK_MAGIC], %o1
+	set	LEONBARE_THREAD_CTX_MAGIC,%o2
+	cmp	%o1, %o2
+	beq	1f
+	 nop
+	
+	/* stop all */
+	ta	0x0
+	
+1:	
+	/* get psr */
+	ld	[%g2 + LEONBARE_THREAD_CTX_STACK_PSR],%g1            /* psr.cwp should stay same because irq path rely on it. */
+	set	SPARC_PSR_EF_MASK,%g3		! clear ef bit
+	andn	%g1, %g3, %g1		
+	
+	wr	%g0,%wim
+	nop; nop; nop;
+
+	andn	%g1, SPARC_PSR_ET_MASK, %g3	! disable traps, up to PSR_EF imm andn ok
+	wr	%g3, %psr
+	nop; nop; nop;
+
+	LEONBARE_THREAD_CTX_LOAD_INS(g2)
+	LEONBARE_THREAD_CTX_LOAD_LOCALS(g2)
+	LEONBARE_THREAD_CTX_LOAD_OUTS(g2)
+	
+	SET_WIM_CWPMIN1(g1,o1,o2,o3,o4)		! calc wim from psr_cwp so that next restore traps
+	
+	wr	%g1,%psr
+	nop; nop; nop;
+	
+	retl
+	 nop
+	
+FUNC_END(_leonbare_kernel_switchto)
+
+
+FUNC_BEGIN(_leonbare_Stop)
+	ta 0x0
+FUNC_END(_leonbare_Stop)